; Dit programmadeel bevat commando #61, bedoeld om een logfile te openen
; zodat alle ingaande en uitgaande bytes opgeslagen worden in een bestand.
; Zodoende kan achteraf gekeken worden waar bepaalde routines de mist in
; gaan.

; commando's: 00 maak/open logfile en start log
;             01 stop log tijdelijk
;             02 herstart log
;             03 einde log, logfile wordt gesloten

LOGFILE         DB      'C:\TEMP\ATOM.LOG',0
LOGHANDLE       DW      ?          ; HANDLE VOOR LOGFILE
LOGWORD         DW      ?          ; DATA VOOR LOGFILE
LOGSTATUS       DB      0          ; STATUS VOOR LOG (aan of uit)

LOGOUT          PROC    NEAR
                PUSH    AX
                PUSH    BX
                PUSH    CX
                PUSH    DX
                MOV     AH,'O'
                MOV     LOGWORD,AX
                MOV     AH,40H
                MOV     BX,LOGHANDLE
                MOV     CX,2
                LEA     DX,LOGWORD
                INT     21H
                POP     DX
                POP     CX
                POP     BX
                POP     AX
                RET
LOGOUT          ENDP

LOGIN           PROC    NEAR
                PUSH    AX
                PUSH    BX
                PUSH    CX
                PUSH    DX
                MOV     AH,'I'
                MOV     LOGWORD,AX
                MOV     AH,40H
                MOV     BX,LOGHANDLE
                MOV     CX,2
                LEA     DX,LOGWORD
                INT     21H
                POP     DX
                POP     CX
                POP     BX
                POP     AX
                RET
LOGIN           ENDP

LOGCOMMS:       CALL    LEESBYTE
                CMP     AL,0
                JE      LOG00
                CMP     AL,1
                JE      LOG01
                CMP     AL,2
                JE      LOG02
                CMP     AL,3
                JE      LOG03
                MOV     FUN_CODE,AL
                JMP     ERROR

LOG00:          MOV     AX,3C01H
                MOV     CX,0
                LEA     DX,LOGFILE
                INT     21H
                JC      LOG021
                MOV     LOGHANDLE,AX
                MOV     LOGSTATUS,1
                JMP     LEESCOM

LOG01:          MOV     LOGSTATUS,0
                JMP     LEESCOM

LOG02:          CMP     LOGHANDLE,0
                JE      LOG021
                MOV     LOGSTATUS,1
LOG021:         JMP     LEESCOM

LOG03:          MOV     BX,LOGHANDLE
                MOV     AH,3EH
                INT     21H
                MOV     LOGHANDLE,0
                MOV     LOGSTATUS,0
                JMP     LEESCOM